Delphi заготовки

// пример функции на Delphi/Pascal которая выводит стандартное окно InpupBox 
но заместо Edit - динамически создаваемый TComBobox  



function GetAveCharSize(Canvas: TCanvas): TPoint;
var
 I: Integer;
 Buffer: array[0..51] of Char;
begin
 for I := 0 to 25 do Buffer[I] := Chr(I + Ord('A'));
 for I := 0 to 25 do Buffer[I + 26] := Chr(I + Ord('a'));
 GetTextExtentPoint(Canvas.Handle, Buffer, 52, TSize(Result));
 Result.X := Result.X div 52;
end;


function InputQueryComBobox(const ACaption, APrompt: string;
 var Value: string;ValueList:string): Boolean;
var
 Form: TForm;
 Prompt: TLabel;
 Edit: Tcombobox;
 DialogUnits: TPoint;
 ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
 Result := False;
 Form := TForm.Create(Application);
 with Form do
 try
 Canvas.Font := Font;
 DialogUnits := GetAveCharSize(Canvas);
 BorderStyle := bsDialog;
 Caption := ACaption;
 ClientWidth := MulDiv(180, DialogUnits.X, 4);
 Position := poScreenCenter;
 Prompt := TLabel.Create(Form);
 with Prompt do
 begin
 Parent := Form;
 Caption := APrompt;
 Left := MulDiv(8, DialogUnits.X, 4);
 Top := MulDiv(8, DialogUnits.Y, 8);
 Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
 WordWrap := True;
 end;
 Edit := Tcombobox.Create(Form);
 with Edit do
 begin
 Edit.Parent:= form;
 Edit.Items.Text:=ValueList;
 Left := Prompt.Left;
 Top := Prompt.Top + Prompt.Height + 5;
 Width := MulDiv(164, DialogUnits.X, 4);
 MaxLength := 255;
 Text := Value;
 SelectAll;
 end;
 ButtonTop := Edit.Top + Edit.Height + 15;
 ButtonWidth := MulDiv(50, DialogUnits.X, 4);
 ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
 with TButton.Create(Form) do
 begin
 Parent := Form;
 Caption := 'Ok';
 ModalResult := mrOk;
 Default := True;
 SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
 ButtonHeight);
 end;
 with TButton.Create(Form) do
 begin
 Parent := Form;
 Caption := 'Отмена';
 ModalResult := mrCancel;
 Cancel := True;
 SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
 ButtonWidth, ButtonHeight);
 Form.ClientHeight := Top + Height + 13; 
 end;
 if ShowModal = mrOk then
 begin
 Value := Edit.Text;
 Result := True;
 end;
 finally
 Form.Free;
 end;
end;

 // Пример применения

 procedure TForm1.Button1Click(Sender: TObject);
var s:string;
begin
 InputQueryComBobox('','',s,'list1'+#13+#10+'list2');
 Showmessage(s);
 end;